FactoryCraft-Client/FactoryCraft/DefaultAnyHit.hlsl

#include "Common.hlsl"

StructuredBuffer<int> textureIdBuffer : register(t1, space2);
StructuredBuffer<int> indexBuffer : register(t1, space3);
StructuredBuffer<VertexData> vertexData : register(t1, space4);
StructuredBuffer<int> polygonSizeBuffer : register(t1, space5);

[shader("anyhit")]
void AnyHit(inout HitInfo rayPayload, SimpleBlocksAttributes attrib)
{
    if (rayPayload.hitCount < 0)
    { // shadow ray
        rayPayload.hitCount = 0;
        // TODO: transparent objects should lead to half shadows
        AcceptHitAndEndSearch();
        return;
    }
    int instanceId = InstanceID();
    int currentTriangle = PrimitiveIndex();
    int textureId = 0;
    int i;
    for (i = 0; currentTriangle >= 0 && polygonSizeBuffer[i] > 0; i++)
    {
        currentTriangle -= polygonSizeBuffer[i];
        textureId = textureIdBuffer[i];
    }
    if (polygonSizeBuffer[i] <= 0)
    {
        // Could not find geometry index, ignore hit
        IgnoreHit();
        return;
    }
    Texture2D<float4> texture = textures[textureId];
    int index = PrimitiveIndex() * 3;

    // Bounds check for vertex indices
    if (indexBuffer[index] < 0 || indexBuffer[index + 1] < 0 || indexBuffer[index + 2] < 0)
    {
        IgnoreHit();
        return;
    }

    VertexData v0 = vertexData[indexBuffer[index]];
    VertexData v1 = vertexData[indexBuffer[index + 1]];
    VertexData v2 = vertexData[indexBuffer[index + 2]];
    float2 texcoord = v0.texcoord * (1 - attrib.bary.x - attrib.bary.y) + v1.texcoord * attrib.bary.x + v2.texcoord * attrib.bary.y;
    float4 color = texture.SampleLevel(gSampler, texcoord, 0);
    if (color.w == 0.f)
    {
        IgnoreHit();
        return;
    }
    float distance = RayTCurrent();
    bool found = false;
    for (i = 0; i < rayPayload.hitCount; i++)
    {
        if (rayPayload.distance[i] > distance)
        {
            found = true;
            float4 tmpColor = rayPayload.color[i];
            rayPayload.color[i] = color;
            float tmpDistance = rayPayload.distance[i];
            rayPayload.distance[i] = distance;
            int tmpDayLight = rayPayload.dayLight[i];
            rayPayload.dayLight[i] = 0xFFFFFF;
            int tmpDynamicLight = rayPayload.dynamicLight[i];
            rayPayload.dynamicLight[i] = 0xFFFFFF;
            if (color.w == 1.f)
            {
                rayPayload.hitCount = i + 1;
            }
            else
            {
                for (int j = i + 1; j < rayPayload.hitCount + 1 && j < MAX_TRANSPACENT_HITS; j++)
                {
                    float4 tmpColor2 = rayPayload.color[j];
                    float tmpDistance2 = rayPayload.distance[j];
                    int tmpDayLight2 = rayPayload.dayLight[j];
                    int tmpDynamicLight2 = rayPayload.dynamicLight[j];
                    rayPayload.color[j] = tmpColor;
                    rayPayload.distance[j] = tmpDistance;
                    rayPayload.dayLight[j] = tmpDayLight;
                    rayPayload.dynamicLight[j] = tmpDynamicLight;
                    tmpColor = tmpColor2;
                    tmpDistance = tmpDistance2;
                    tmpDayLight = tmpDayLight2;
                    tmpDynamicLight = tmpDynamicLight2;
                }
            }
            break;
        }
        else
        {
            if (rayPayload.color[i].w == 1.f)
            {
                found = true;
                break;
            }
        }
    }
    if (!found && rayPayload.hitCount < MAX_TRANSPACENT_HITS)
    {
        rayPayload.color[rayPayload.hitCount] = color;
        rayPayload.distance[rayPayload.hitCount] = distance;
        rayPayload.dayLight[rayPayload.hitCount] = 0xFFFFFF;
        rayPayload.dynamicLight[rayPayload.hitCount] = 0xFFFFFF;
        rayPayload.hitCount++;
    }
    if (color.w < 1.f)
    {
        IgnoreHit();
        return;
    }
}